Windows 11 İşletim Sisteminde İnternet ve VPN Bağlantı Sorunları Gidermek

Windows işletim sistemlerinde zaman zaman internet bağlantısı, VPN erişimi, DNS çözümleme, IP alma, Wi-Fi bağlantısı veya ağ bağdaştırıcılarıyla ilgili çeşitli problemler yaşanabilir.

Özellikle kurumsal ortamlarda çalışan kullanıcılar için bu tür sorunlar iş sürekliliğini doğrudan etkileyebilir. İnternetin çalışmaması, VPN bağlantısının kurulamaması, DNS kayıtlarının doğru çözümlenememesi veya IP adresinin yenilenememesi gibi durumlar, çoğu zaman birkaç temel ağ komutuyla çözülebilmektedir.

Windows üzerinde bu tür problemleri gidermek için sık kullanılan bazı komutlar vardır. Örneğin netsh winsock reset, netsh int ip reset, ipconfig /flushdns, ipconfig /release, ipconfig /renew, nbtstat -R ve nbtstat -RR gibi komutlar, ağ yapılandırmasını onarmak veya geçici önbellekleri temizlemek için oldukça faydalıdır.

Ancak bu komutların tamamını akılda tutmak her zaman kolay değildir. Çoğu zaman bağlantı sorunu yaşandığında internetten bu komutlar aranır, Komut İstemi yönetici olarak açılır ve komutlar tek tek kopyalanıp çalıştırılır. Bu işlem hem zaman kaybına neden olur hem de eksik veya hatalı komut çalıştırma ihtimalini artırır.

Bu süreci daha pratik hale getirmek amacıyla hazırlanan Network Repair Tools isimli BAT script’i yaygın ağ onarım ve sıfırlama işlemlerini tek bir menü altında toplamaktadır.

Bu scirpt sayesinde internet, VPN, DNS, IP, NetBIOS, ARP, ağ bağdaştırıcıları ve Windows Güvenlik Duvarı ile ilgili birçok temel onarım işlemi birkaç adımda uygulanabilir.

Network Repair Tools Nedir?

Network Repair Tools, Windows sistemlerde sık karşılaşılan ağ bağlantı problemlerini gidermek için hazırlanmış bir BAT betiğidir. Betik, Windows’un yerleşik ağ komutlarını kullanarak çeşitli onarım işlemlerini otomatikleştirir.

Bu araç sayesinde kullanıcı veya IT destek personeli, komutları tek tek yazmak yerine menü üzerinden ilgili işlemi seçerek ağ onarım sürecini başlatabilir.

Betik genel olarak şu işlemleri gerçekleştirebilir:

Windows ağ onarımı
TCP/IP ve Winsock sıfırlama
DNS önbelleği temizleme
DNS kayıtlarını yeniden kaydetme
IP adresini bırakma ve yenileme
ARP ve ağ komşuluk önbelleğini temizleme
NetBIOS isim tablolarını yenileme
Wi-Fi profillerini yedekleme
Gelişmiş ağ bağdaştırıcı sıfırlama
Windows Güvenlik Duvarı ayarlarını sıfırlama

Bu işlemler özellikle internet bağlantısı çalışmadığında, VPN bağlantısı kurulamadığında, DNS çözümleme problemleri yaşandığında veya ağ bağdaştırıcılarında bozulma meydana geldiğinde oldukça kullanışlıdır.

Neden Böyle Bir Araca İhtiyaç Duyulur?

Ağ problemleri çoğu zaman kullanıcı tarafında benzer belirtilerle ortaya çıkar. Örneğin kullanıcı internete çıkamadığını, VPN’e bağlanamadığını veya bazı web sitelerine erişemediğini söyler. Fakat bu problemin arkasında farklı sebepler olabilir.

Bunlardan bazıları şunlardır:

DNS önbelleğinin bozulması, IP adresinin doğru alınamaması, Winsock kataloğunda hata oluşması, TCP/IP yapılandırmasının zarar görmesi, VPN istemcisinin ağ bağdaştırıcılarını bozması, sanal ağ adaptörlerinin çakışması, Windows Güvenlik Duvarı kurallarının bağlantıyı engellemesi veya Wi-Fi profil bilgilerinin sorunlu hale gelmesi.

Bu tür durumlarda IT destek ekipleri genellikle belirli komutları sırasıyla çalıştırarak sistemi temizlemeye ve ağ yapılandırmasını yeniden oluşturmaya çalışır. Network Repair Tools tam olarak bu noktada devreye girer ve sık kullanılan işlemleri daha düzenli, hızlı ve güvenli şekilde çalıştırmayı amaçlar.

Betiğin Menü Yapısı

Network Repair Tools çalıştırıldığında kullanıcıya basit bir menü sunar. Bu menü üzerinden yapılacak işlem seçilebilir.

Araç içerisinde temel olarak şu seçenekler yer almaktadır:

Windows Ağ Onarımı
Gelişmiş Bütün Ağ Bağlaştırıcı Ayarlarını Sıfırla
Wi-Fi Profillerini Yedekleme
Windows Güvenlik Duvarı Ayarlarını Sıfırla
Yardım ve Kullanım Bilgileri
Çıkış

Bu yapı sayesinde kullanıcı doğrudan ihtiyacı olan işlemi seçebilir. Özellikle teknik destek süreçlerinde bu tarz menülü araçlar, işlem hatalarını azaltır ve destek süresini kısaltır.

Yönetici Yetkisi Kontrolü

Betiğin önemli özelliklerinden biri, yönetici yetkisi kontrolü yapmasıdır. Windows üzerinde netsh, ipconfig /registerdns, netcfg -d ve güvenlik duvarı sıfırlama gibi birçok işlem için yönetici yetkisi gerekir.

Betik çalıştırıldığında önce yönetici yetkisi kontrol edilir. Eğer betik normal kullanıcı yetkisiyle açılmışsa, PowerShell üzerinden kendisini yönetici olarak yeniden çalıştırmayı dener. Bu sayede kullanıcı Komut İstemi’ni ayrıca yönetici olarak açmak zorunda kalmadan işlemleri gerçekleştirebilir.

Bu özellik, özellikle son kullanıcı tarafında kullanım kolaylığı sağlar. Ancak yine de betiğin güvenilir bir kaynaktan geldiğinden emin olunmalı ve içeriği çalıştırmadan önce incelenmelidir.

Windows Ağ Onarımı Seçeneği

Betiğin birinci seçeneği olan Windows Ağ Onarımı, genel internet ve VPN sorunlarında ilk uygulanması önerilen bölümdür. Bu seçenek, mevcut ağ yapılandırmasına genellikle büyük zarar vermeden temel ağ bileşenlerini temizler ve yeniler.

Bu bölümde sırasıyla Winsock, TCP/IP, IPv4, IPv6, DNS, ARP, NetBIOS ve IP yenileme işlemleri yapılır.

Winsock Sıfırlama

netsh winsock reset komutu, Windows’un Winsock kataloğunu varsayılan haline döndürür. Winsock, uygulamaların ağ üzerinden iletişim kurmasını sağlayan önemli bir Windows bileşenidir.

Bazı VPN yazılımları, güvenlik yazılımları, proxy araçları veya üçüncü parti ağ uygulamaları Winsock yapısında değişiklik yapabilir. Bu yapı bozulduğunda internet bağlantısı kopabilir, tarayıcılar açılmayabilir veya bazı uygulamalar internete erişemeyebilir.

Winsock sıfırlama işlemi bu tür sorunlarda oldukça etkili olabilir.

TCP/IP Yapılandırmasını Sıfırlama

netsh int ip reset komutu, TCP/IP yapılandırmasını varsayılan değerlere döndürür. TCP/IP, Windows’un ağ iletişiminin temelini oluşturur. Bu yapılandırmada meydana gelen bozulmalar, IP alamama, ağ geçidine erişememe veya DNS sunucularıyla iletişim kuramama gibi sorunlara yol açabilir.

Betiğin içerisinde ayrıca IPv4 ve IPv6 yapılandırmaları için de sıfırlama komutları bulunmaktadır:

netsh int ipv4 reset

netsh int ipv6 reset

Bu komutlar sayesinde hem IPv4 hem de IPv6 ağ yapılandırmaları yeniden düzenlenir.

Ağ Komşulukları ve Hedef Önbelleği Temizleme

Betiğin ikinci aşamasında ağ komşulukları ve yönlendirme önbelleği temizlenir.

Bu işlem için kullanılan komutlar, sistemin daha önce öğrendiği ağ komşularını ve hedef önbelleğini temizlemeye yardımcı olur. Özellikle aynı ağda IP değişikliği, gateway değişikliği, VLAN değişikliği veya VPN sonrası yönlendirme problemleri yaşanıyorsa bu temizlik faydalı olabilir.

ARP Önbelleğini Temizleme

ARP, IP adresleri ile MAC adresleri arasındaki eşleştirmeyi sağlayan protokoldür. Windows, ağdaki cihazlarla iletişim kurarken bu eşleştirmeleri önbellekte tutar.

Ancak bazı durumlarda ARP tablosu hatalı veya eski bilgiler içerebilir. Bu da ağdaki cihazlara erişim sorunlarına neden olabilir.

Betiğin bu aşamasında ARP önbelleği temizlenir. Bu işlem özellikle yerel ağda dosya paylaşımı, yazıcı erişimi, gateway erişimi veya VPN sonrası bağlantı sorunlarında işe yarayabilir.

NetBIOS İsim Tablolarını Yenileme

Betiğin bir diğer adımı NetBIOS isim tablolarını temizlemek ve yeniden kaydetmektir.

Bu işlem için şu komutlar kullanılır:

nbtstat -R
nbtstat -RR

NetBIOS günümüzde her ortamda yoğun olarak kullanılmasa da bazı eski sistemlerde, dosya paylaşımı senaryolarında veya kurumsal ağlarda hâlâ önemli olabilir. Özellikle bilgisayar adıyla erişimlerde problem yaşanıyorsa NetBIOS önbelleğinin temizlenmesi faydalı olabilir.

DNS Önbelleğini Temizleme ve DNS Kayıtlarını Yenileme

DNS sorunları, internet bağlantısı problemlerinin en sık karşılaşılan nedenlerinden biridir. Kullanıcı internete bağlı görünse bile web sitelerine erişemeyebilir veya şirket içi sistemlere isim üzerinden ulaşamayabilir.

Bu durumda DNS önbelleğinin temizlenmesi gerekir.

Betiğin bu aşamasında şu komutlar çalıştırılır;

ipconfig /flushdns
ipconfig /registerdns

ipconfig /flushdns komutu, bilgisayarda tutulan DNS önbelleğini temizler. Böylece hatalı veya eski DNS kayıtları silinir.

ipconfig /registerdns komutu ise bilgisayarın DNS kayıtlarını yeniden kaydetmesini sağlar. Bu işlem özellikle domain ortamlarında, Active Directory yapılarında ve kurumsal DNS sunucularının kullanıldığı sistemlerde faydalıdır.

IP Adresini Bırakma ve Yenileme

Betiğin son aşamasında mevcut IP adresi bırakılır ve DHCP sunucusundan yeni IP adresi talep edilir.

Bu işlem için şu komutlar kullanılır;

ipconfig /release
ipconfig /renew

ipconfig /release mevcut IP adresini bırakır. ipconfig /renew ise DHCP sunucusundan yeni bir IP adresi alınmasını sağlar.

Bu işlem özellikle IP çakışması, yanlış IP alma, DHCP’den IP alamama veya VPN sonrası ağ yapılandırmasının bozulması gibi durumlarda yararlı olabilir.

Gelişmiş Ağ Bağdaştırıcı Sıfırlama

Betiğin ikinci seçeneği olan Gelişmiş Bütün Ağ Bağlaştırıcı Ayarlarını Sıfırla, daha kapsamlı bir işlemdir. Bu bölüm, standart ağ onarımından daha derin bir sıfırlama yapar.

Bu bölümde öne çıkan komut şudur;

netcfg -d

Bu komut, Windows üzerindeki ağ bağdaştırıcılarını ve ağ yapılandırmasını kaldırıp yeniden oluşturur. Bu nedenle standart komutlarla çözülemeyen daha karmaşık ağ problemlerinde kullanılabilir.

Örneğin VPN istemcilerinin oluşturduğu sanal adaptörler, VMware veya VirtualBox gibi sanallaştırma yazılımlarının ağ bağdaştırıcıları, eski sürücüler, bozulmuş ağ bileşenleri veya hatalı yapılandırmalar bu işlemden etkilenebilir.

Ancak bu seçenek dikkatli kullanılmalıdır.

Çünkü netcfg -d işlemi sonrasında daha önce tanımlanmış bazı ayarlar silinebilir. Bunlara statik IP adresleri, özel DNS tanımları, VPN yapılandırmaları, sanal ağ adaptörleri, Hyper-V/VMware/VirtualBox ağ ayarları ve özel bağlantı yapılandırmaları dahil olabilir.

Bu nedenle gelişmiş sıfırlama işlemi, ilk çözüm adımı olarak değil; standart Windows ağ onarımı ile sonuç alınamadığında tercih edilmelidir.

İşlem sonrasında bilgisayarın yeniden başlatılması önemlidir. Yeniden başlatma yapılmadan tüm ağ bileşenleri sağlıklı şekilde yeniden oluşmayabilir.

Wi-Fi Profillerini Yedekleme Özelliği

Windows ağ sıfırlama işlemlerinin en can sıkıcı sonuçlarından biri kayıtlı Wi-Fi profillerinin ve şifrelerinin silinebilmesidir. Özellikle birçok farklı kablosuz ağa bağlanan kullanıcılar için bu durum zaman kaybına neden olabilir.

Network Repair Tools içerisinde bu sorunu azaltmak için Wi-Fi profil yedekleme özelliği bulunmaktadır.

Bu özellik, bilgisayarda kayıtlı olan Wi-Fi profillerini Masaüstü üzerinde oluşturulan WiFi_Yedek klasörüne aktarır. Yedekleme işlemi sırasında Wi-Fi profilleri XML formatında dışa aktarılır.

Bu işlem için kullanılan temel komut şudur;

netsh wlan export profile key=clear

Buradaki önemli nokta key=clear parametresidir. Bu parametre sayesinde Wi-Fi şifreleri de XML dosyalarının içerisine okunabilir şekilde aktarılır.

Bu özellik geri yükleme açısından kullanışlıdır; ancak güvenlik açısından dikkat edilmesi gereken önemli bir noktadır. Çünkü yedeklenen XML dosyalarına erişen bir kişi, kayıtlı Wi-Fi şifrelerini görebilir.

Bu nedenle Wi-Fi yedek klasörü güvenli bir yerde saklanmalı, yetkisiz kişilerle paylaşılmamalı ve ihtiyaç kalmadığında silinmelidir.

Wi-Fi Profillerini Geri Yükleme

Betiğin Wi-Fi yedekleme bölümünde yalnızca profiller dışa aktarılmaz; aynı zamanda geri yükleme için kullanılabilecek bir Kur.bat dosyası da oluşturulur.

Bu dosya, yedeklenen XML profillerini tekrar Windows’a eklemek için kullanılır. Böylece ağ sıfırlama işleminden sonra Wi-Fi profillerinin tek tek elle girilmesine gerek kalmaz.

Bu özellik özellikle format sonrası, bilgisayar değişimlerinde veya gelişmiş ağ sıfırlama işleminden sonra oldukça kullanışlıdır.

Yine de geri yükleme dosyasının yönetici yetkisiyle çalıştırılması gerekebilir.

Windows Güvenlik Duvarı Ayarlarını Sıfırlama

Betiğin dördüncü seçeneği Windows Güvenlik Duvarı ayarlarını sıfırlamak için hazırlanmıştır.

Bu bölümde kullanılan komut şudur;

netsh advfirewall reset

Bu komut, Windows Güvenlik Duvarı ayarlarını varsayılan değerlere döndürür. Daha önce oluşturulmuş özel kurallar, izinler veya engellemeler bu işlemle kaldırılabilir.

Bu seçenek özellikle bazı uygulamaların internete çıkamaması, VPN bağlantısının firewall nedeniyle engellenmesi, yanlışlıkla oluşturulan güvenlik duvarı kuralları veya kural çakışmaları gibi durumlarda kullanılabilir.

Ancak bu işlem dikkatli uygulanmalıdır. Çünkü kurumsal sistemlerde özel olarak tanımlanmış güvenlik duvarı kuralları olabilir. Bu kuralların silinmesi, bazı uygulamaların çalışma şeklini değiştirebilir veya güvenlik politikalarını etkileyebilir.

Bu nedenle firewall sıfırlama işlemi yapılmadan önce mevcut kuralların gerekli olup olmadığı değerlendirilmelidir.

Hangi Seçenek Ne Zaman Kullanılmalı?

Network Repair Tools içerisindeki seçeneklerin doğru sırayla kullanılması önemlidir.

Genel internet, DNS veya VPN bağlantı sorunlarında öncelikle Windows Ağ Onarımı seçeneği kullanılmalıdır. Bu seçenek daha güvenli ve daha az müdahalecidir.

Eğer standart onarım işlemi sorunu çözmezse ve ağ bağdaştırıcılarıyla ilgili daha derin bir problem olduğu düşünülüyorsa Gelişmiş Ağ Bağdaştırıcı Ayarlarını Sıfırla seçeneği değerlendirilebilir.

Ağ sıfırlama işlemlerinden önce kayıtlı kablosuz ağları kaybetmemek için Wi-Fi Profillerini Yedekleme seçeneği kullanılabilir.

Bağlantı probleminin Windows Güvenlik Duvarı kurallarından kaynaklandığı düşünülüyorsa Windows Güvenlik Duvarı Ayarlarını Sıfırla seçeneği tercih edilebilir.

Kullanım Öncesi Dikkat Edilmesi Gerekenler

Bu tür ağ onarım betikleri genel olarak Windows’un yerleşik komutlarını kullansa da çalıştırmadan önce dikkatli olunmalıdır.

Öncelikle betik içeriği mutlaka incelenmelidir. İnternetten indirilen veya farklı kaynaklardan alınan BAT dosyaları doğrudan çalıştırılmamalıdır. BAT dosyaları sistem üzerinde değişiklik yapabilecek komutlar içerebilir.

İkinci olarak, betik yönetici yetkisiyle çalıştırılmalıdır. Ağ sıfırlama ve firewall işlemleri standart kullanıcı yetkisiyle tamamlanamayabilir.

Üçüncü olarak, gelişmiş ağ sıfırlama işlemi öncesinde mevcut statik IP, DNS, VPN ve sanal ağ ayarları not alınmalıdır. Çünkü gelişmiş sıfırlama sonrasında bu ayarların yeniden yapılandırılması gerekebilir.

Dördüncü olarak, Wi-Fi profilleri yedeklenirken şifrelerin açık şekilde dışa aktarılabileceği unutulmamalıdır. Bu dosyalar güvenli şekilde saklanmalıdır.

Son olarak, birçok ağ sıfırlama işleminin tam olarak etkili olabilmesi için sistemin yeniden başlatılması gerekir. Bu nedenle işlemler mümkünse kullanıcı çalışmalarını kaydettikten sonra uygulanmalıdır.

İndirilen BAT Dosyaları İçin Engellemeyi Kaldırma

Windows, internetten indirilen bazı dosyaları güvenlik nedeniyle engelleyebilir. Bu durumda BAT dosyası doğru şekilde çalışmayabilir veya Windows güvenlik politikaları nedeniyle engellenebilir.

Bu nedenle dosya indirildikten sonra çalıştırmadan önce şu adımlar uygulanmalıdır:

Dosyaya sağ tıklanır, Özellikler penceresi açılır ve eğer görünüyorsa Engellemeyi Kaldır seçeneği işaretlenir. Ardından Uygula ve Tamam butonlarına basılır.

Bu işlemden sonra betik tekrar çalıştırılabilir.

Network Repair Tools, Windows üzerinde sık yaşanan internet, VPN, DNS, IP ve ağ bağdaştırıcı problemlerini gidermek için hazırlanmış pratik bir yardımcı araçtır. Tek tek komut yazmak yerine menü üzerinden işlem yapılabilmesi, özellikle IT destek süreçlerinde zaman kazandırır.

Standart ağ onarımı bölümü, günlük bağlantı problemlerinde ilk uygulanabilecek güvenli bir adımdır. Gelişmiş ağ sıfırlama seçeneği ise daha karmaşık ve standart yöntemlerle çözülemeyen sorunlar için güçlü bir alternatiftir. Wi-Fi profil yedekleme özelliği, ağ sıfırlama işlemleri sonrasında kablosuz ağ bilgilerinin kaybolmasını önlemeye yardımcı olur. Windows Güvenlik Duvarı sıfırlama bölümü ise bağlantıyı engelleyen hatalı firewall kurallarının temizlenmesinde kullanılabilir.

Her ne kadar betik Windows’un yerleşik sistem komutlarını kullansa da, çalıştırmadan önce içeriğin incelenmesi ve özellikle gelişmiş sıfırlama işlemlerinin dikkatli uygulanması önemlidir.

Doğru kullanıldığında bu tür araçlar, hem son kullanıcılar hem de IT destek ekipleri için oldukça faydalı ve zaman kazandırıcı çözümler sunar.

@echo off
setlocal EnableExtensions
chcp 65001 >nul
title Network Repair Tools
color A

:: ==========================================================
:: Administrator Privilege Check
:: ==========================================================
net session >nul 2>&1
if errorlevel 1 (
    powershell -NoProfile -ExecutionPolicy Bypass -Command "Start-Process -FilePath '%~f0' -Verb RunAs"
    exit /b
)

:Menu
color A
title Network Repair Tools
cls
echo ==========================================
echo            NETWORK REPAIR TOOLS
echo ==========================================
echo.
echo [1] Windows Network Repair - Recommended
echo [2] Advanced Network Adapter Reset
echo [3] Backup Wi-Fi Profiles
echo [4] Reset Windows Firewall Settings
echo [5] Help and Usage Information
echo [6] Exit
echo.

set "Choice="
set /p Choice=Please select an option: 

if "%Choice%"=="1" goto Repair
if "%Choice%"=="2" goto Advanced
if "%Choice%"=="3" goto Backup
if "%Choice%"=="4" goto Firewall
if "%Choice%"=="5" goto Info
if "%Choice%"=="6" exit /b

goto Menu


:Repair
title Windows Network Repair
color 3
cls
echo ==========================================
echo          WINDOWS NETWORK REPAIR
echo ==========================================
echo.
echo This process will reset common Windows network components.
echo Internet, DNS, VPN, and general connectivity issues may be resolved.
echo.
echo [WARNING] Your active network connection may be temporarily disconnected.
echo.

pause

echo.
echo [1/6] Resetting Winsock and TCP/IP stack...
netsh winsock reset >nul 2>&1
netsh int ip reset >nul 2>&1
netsh int ipv4 reset >nul 2>&1
netsh int ipv6 reset >nul 2>&1

echo.
echo [2/6] Clearing neighbor and destination cache...
netsh int ip delete neighbors >nul 2>&1
netsh int ip delete destinationcache >nul 2>&1

echo.
echo [3/6] Clearing ARP cache...
netsh int ip delete arpcache >nul 2>&1
arp -d * >nul 2>&1

echo.
echo [4/6] Refreshing NetBIOS name cache...
nbtstat -R >nul 2>&1
nbtstat -RR >nul 2>&1

echo.
echo [5/6] Flushing DNS cache and re-registering DNS records...
ipconfig /flushdns >nul 2>&1
ipconfig /registerdns >nul 2>&1

echo.
echo [6/6] Releasing and renewing IP address...
ipconfig /release >nul 2>&1
ipconfig /renew >nul 2>&1

echo.
echo ============================================================
echo Network repair process has been completed.
echo A system restart is strongly recommended for all changes
echo to take full effect.
echo ============================================================
echo.

set "RestartChoice="
set /p RestartChoice=Do you want to restart the computer now? (Y/N): 

if /I "%RestartChoice%"=="Y" goto Reboot

echo.
echo Restart skipped. Returning to main menu...
timeout /t 3 >nul
goto Menu


:Advanced
cls
title Advanced Network Adapter Reset
color E
echo ======================================================
echo          ADVANCED NETWORK ADAPTER RESET
echo ======================================================
echo.
echo This option performs a deep network reset using netcfg -d.
echo.
echo [IMPORTANT WARNING]
echo This process may remove or reset:
echo - Static IP settings
echo - VPN adapters
echo - Virtual adapters such as VMware, VirtualBox, Hyper-V
echo - Custom DNS settings
echo - Manually configured network profiles
echo.
echo Wi-Fi profiles will be backed up before the reset.
echo.
pause

call :BackupWifiProfiles

echo.
echo Performing advanced network adapter reset...
netcfg -d

echo.
echo Advanced network adapter reset has been completed.
echo A restart is required for Windows to reinstall network adapters.
echo.

set "RestartChoice="
set /p RestartChoice=Do you want to restart the computer now? (Y/N): 

if /I "%RestartChoice%"=="Y" goto Reboot

echo.
echo Restart skipped. Returning to main menu...
timeout /t 3 >nul
goto Menu


:Backup
cls
title Backup Wi-Fi Profiles
color E
echo ======================================================
echo              BACKUP WI-FI PROFILES
echo ======================================================
echo.
call :BackupWifiProfiles
pause
goto Menu


:BackupWifiProfiles
echo.
echo Backing up saved Wi-Fi profiles...
echo.

for /f "usebackq delims=" %%D in (`powershell -NoProfile -Command "[Environment]::GetFolderPath('Desktop')"`) do set "DESKTOP_PATH=%%D"

set "BACKUP_DIR=%DESKTOP_PATH%\WiFi_Backup"

if not exist "%BACKUP_DIR%" (
    mkdir "%BACKUP_DIR%"
)

netsh wlan export profile key=clear folder="%BACKUP_DIR%" >nul 2>&1

(
    echo @echo off
    echo chcp 65001 ^>nul
    echo color A
    echo title Restore Wi-Fi Profiles
    echo.
    echo :: ==========================================================
    echo :: Administrator Privilege Check
    echo :: ==========================================================
    echo net session ^>nul 2^>^&1
    echo if errorlevel 1 ^(
    echo     powershell -NoProfile -ExecutionPolicy Bypass -Command "Start-Process -FilePath '%%~f0' -Verb RunAs"
    echo     exit /b
    echo ^)
    echo.
    echo cd /d "%%~dp0"
    echo echo Restoring Wi-Fi profiles...
    echo.
    echo for %%%%F in ^(*.xml^) do ^(
    echo     echo Importing: %%%%~nxF
    echo     netsh wlan add profile filename="%%%%~fF" user=all
    echo ^)
    echo.
    echo echo.
    echo echo Wi-Fi profile restore process has been completed.
    echo pause
) > "%BACKUP_DIR%\Restore_WiFi_Profiles.bat"

echo.
echo Wi-Fi profiles have been backed up successfully.
echo Backup folder:
echo "%BACKUP_DIR%"
echo.
echo [SECURITY WARNING]
echo Wi-Fi passwords are exported in clear text inside XML files.
echo Keep this folder in a secure location and delete it when it is no longer needed.
echo.
exit /b


:Firewall
cls
color C
title Reset Windows Firewall Settings

echo ======================================================
echo             RESET WINDOWS FIREWALL SETTINGS
echo ======================================================
echo.
echo This process will restore Windows Firewall settings
echo to their default values.
echo.
echo [WARNING]
echo Custom firewall rules, application permissions,
echo and manually created allow/block rules may be removed.
echo.

set "FirewallChoice="
set /p FirewallChoice=Do you want to reset Windows Firewall settings? (Y/N): 

if /I "%FirewallChoice%"=="Y" goto FirewallReset

echo.
echo Operation cancelled. Returning to main menu...
timeout /t 2 >nul
goto Menu


:FirewallReset
echo.
echo Resetting Windows Firewall settings...
netsh advfirewall reset

echo.
echo Windows Firewall settings have been reset successfully.
echo.
pause
goto Menu


:Info
title Network Repair Tools - Help
cls
color 0F
echo ====================================================================
echo              HELP, USAGE AND TOOL INFORMATION
echo ====================================================================
echo.
echo This tool was developed by Isa Erdogan / IT Support to speed up
echo troubleshooting processes for common network, internet, DNS and VPN
echo connectivity issues.
echo.
echo [1] Windows Network Repair - Recommended
echo     Resets Winsock and TCP/IP stack, clears DNS, ARP and NetBIOS
echo     cache, then releases and renews the current IP address.
echo.
echo     Recommended for:
echo     - Internet connection problems
echo     - DNS resolution issues
echo     - VPN connection problems
echo     - Slow or unstable network behavior
echo.
echo [2] Advanced Network Adapter Reset
echo     Performs a deeper reset using the netcfg -d command.
echo     This removes and reinstalls network adapters.
echo.
echo     [WARNING]
echo     This option may remove static IP settings, VPN adapters,
echo     virtual network adapters and custom DNS/network configurations.
echo.
echo [3] Backup Wi-Fi Profiles
echo     Exports all saved Wi-Fi profiles to the Desktop under the
echo     WiFi_Backup folder. A restore script is also created.
echo.
echo     [SECURITY WARNING]
echo     Since key=clear is used, Wi-Fi passwords are stored in clear text
echo     inside XML files. Keep the backup folder secure.
echo.
echo [4] Reset Windows Firewall Settings
echo     Restores Windows Firewall rules to default values.
echo     This may fix issues caused by incorrect or conflicting firewall rules.
echo.
echo Important:
echo After using option [1] or [2], restarting the computer is strongly
echo recommended for the changes to fully apply.
echo.
echo ====================================================================
echo        Wishing you secure and stable systems.
echo        Isa Erdogan - IT Support
echo ====================================================================
echo.
pause
goto Menu


:Reboot
echo.
echo The computer will restart in 5 seconds...
shutdown -r -t 5
exit /b